mirror of
https://github.com/vale981/emacs-jupyter
synced 2025-03-04 15:41:37 -05:00
8fc5f0bbee
This change localizes all `zmq` related functionality to `jupyter-ioloop` and `jupyter-zmq-*` files. * jupyter-channel-ioloop-comm.el: Add better commentary. (jupyter-base): Require. (jupyter-channel-ioloop-comm): Add `ioloop-class` slot (initialize-instance [jupyter-channel-ioloop-comm]): Use it. * jupyter-channel-ioloop.el (jupyter-base, jupyter-zmq-channel): Un-require. (jupyter-ioloop-session, jupyter-ioloop-channels): Rename to `jupyter-channel-ioloop-session` `jupyter-channel-ioloop-channels` and update all callers. (jupyter-channel-ioloop): Make into an abstract class. (initialize-instance [jupyter-channel-ioloop]): Re-add `jupyter-channel-ioloop-add-send-event`. Don't add to `jupyter-ioloop-post-hook`. (jupyter-channel-ioloop-recv-messages): Remove. (jupyter-channel-ioloop--set-session, jupyter-ioloop-start) (jupyter-channel-ioloop-add-send-event): Doc changes. (jupyter-channel-ioloop-add-start-channel-event) (jupyter-channel-ioloop-add-stop-channel-event): Don't add/remove from the `jupyter-ioloop-poller`. Now expected to be handled in the `jupyter-channel` subclass. Update documentation. In addition, for the start-channel event, do not attempt to add a channel if one doesn't already exist. * jupyter-ioloop.el (jupyter-ioloop-add-teardown): Remove mention of `jupyter-channel-ioloop` behavior. (jupyter-ioloop-add-arg-type): Update example variable. (jupyter-ioloop-environment-p): New function. * jupyter-kernel-manager.el (jupyter-channel): Require. (jupyter-make-client): Require and use `jupyter-zmq-channel-ioloop`. (jupyter-start-channels): Use `make-instance`. (jupyter-interrupt-kernel): Remove `condition-case`. Not needed since preventing socket blocking is now handled by `jupyter-recv`. * jupyter-repl.el (jupyter-connect-repl): Require and use `jupyter-zmq-channel-ioloop`. * jupyter-zmq-channel-ioloop.el: New file. * jupyter-zmq-channel.el (jupyter-ioloop-poller-remove) (jupyter-ioloop-poller-add): New declares. (jupyter-start-channel): Add to `jupyter-ioloop-poller` when in `jupyter-ioloop-environment-p`. (jupyter-stop-channel): Only disconnect the socket from its endpoint instead of closing it, leave that up to garbage collection. Remove from `jupyter-ioloop-poller` when in `jupyter-ioloop-environment-p`. (jupyter-recv): Handle non-blocking. * test/jupyter-test.el (jupyter-zmq-channel): Use non-blocking `zmq-send` since socket is no longer closed when calling `jupyter-stop-channel`. (jupyter-ioloop-test-eval-ioloop): Rename to `jupyter-test-ioloop-eval-event`, update all callers, and move to `test/test-helper.el`. (jupyter-channel-ioloop-send-event, jupyter-channel-ioloop-stop-channel-event) (jupyter-channel-ioloop-start-channel-event): Fix tests for variable name changes. Use `jupyter-test-channel-ioloop`. Update `jupyter-ioloop-poller`, addition/removal from poller is now done in the `jupyter-channel` subclass by checking `jupyter-ioloop-environment-p`. * test/test-helper.el (jupyter-zmq-channel-ioloop): Require. (initialize-instance [jupyter-echo-client]): Use it. (jupyter-test-channel-ioloop): New macro. (jupyter-test-ioloop-eval-event): New function.
163 lines
6.8 KiB
EmacsLisp
163 lines
6.8 KiB
EmacsLisp
;;; jupyter-channel-ioloop-comm.el --- Communication layer using jupyter-channel-ioloop -*- lexical-binding: t -*-
|
|
|
|
;; Copyright (C) 2019 Nathaniel Nicandro
|
|
|
|
;; Author: Nathaniel Nicandro <nathanielnicandro@gmail.com>
|
|
;; Created: 27 Jun 2019
|
|
;; Version: 0.8.0
|
|
|
|
;; This program is free software; you can redistribute it and/or
|
|
;; modify it under the terms of the GNU General Public License as
|
|
;; published by the Free Software Foundation; either version 3, or (at
|
|
;; your option) any later version.
|
|
|
|
;; This program is distributed in the hope that it will be useful, but
|
|
;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
;; General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs; see the file COPYING. If not, write to the
|
|
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
;; Boston, MA 02111-1307, USA.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Implements the `jupyter-comm-layer' interface on-top of a `jupyter-ioloop'
|
|
;; subclass that implements the `jupyter-channel' interface through events sent
|
|
;; to the ioloop. The `jupyter-ioloop' must implement a start-channel,
|
|
;; stop-channel, and a send event. For the start-channel and stop-channel
|
|
;; events the `jupyter-ioloop' must send back a list like
|
|
;;
|
|
;; (start-channel :hb) or (stop-channel :shell)
|
|
;;
|
|
;; for confirmation that the corresponding channel was indeed started or
|
|
;; stopped. The start-channel event should accept two arguments, (CHANNEL
|
|
;; ENDPOINT), used to start CHANNEL. The stop-channel event should accept a
|
|
;; single argument, CHANNEL, and stop the channel in the `jupyter-ioloop'
|
|
;; environment.
|
|
;;
|
|
;; Initializing the connection
|
|
;;
|
|
;; The `jupyter-initialize-connection' method should be called before calling
|
|
;; `jupyter-comm-start' and should be passed a `jupyter-session' object used to
|
|
;; initialize the `jupyter-channel-ioloop' object.
|
|
|
|
;;; Code:
|
|
|
|
(require 'jupyter-base)
|
|
(require 'jupyter-ioloop-comm)
|
|
(require 'jupyter-channel-ioloop)
|
|
|
|
(cl-defstruct jupyter-proxy-channel endpoint alive-p)
|
|
|
|
(defclass jupyter-channel-ioloop-comm (jupyter-ioloop-comm
|
|
jupyter-hb-comm
|
|
jupyter-comm-autostop)
|
|
((ioloop-class :type class :initarg :ioloop-class)
|
|
(session :type jupyter-session)
|
|
(iopub :type jupyter-proxy-channel)
|
|
(shell :type jupyter-proxy-channel)
|
|
(stdin :type jupyter-proxy-channel)))
|
|
|
|
(cl-defmethod initialize-instance ((comm jupyter-channel-ioloop-comm) &optional _slots)
|
|
(cl-call-next-method)
|
|
(unless (slot-boundp comm 'ioloop-class)
|
|
(oset comm ioloop-class 'jupyter-channel-ioloop))
|
|
(with-slots (ioloop-class) comm
|
|
(jupyter-error-if-not-client-class-p ioloop-class 'jupyter-channel-ioloop)
|
|
(oset comm ioloop (make-instance ioloop-class))))
|
|
|
|
(cl-defmethod jupyter-comm-id ((comm jupyter-channel-ioloop-comm))
|
|
(format "session=%s" (truncate-string-to-width
|
|
(jupyter-session-id (oref comm session))
|
|
9 nil nil "…")))
|
|
|
|
(cl-defmethod jupyter-initialize-connection ((comm jupyter-channel-ioloop-comm)
|
|
(session jupyter-session))
|
|
(cl-call-next-method)
|
|
(let ((endpoints (jupyter-session-endpoints session)))
|
|
(oset comm session (copy-sequence session))
|
|
(oset comm hb (make-instance
|
|
'jupyter-hb-channel
|
|
:session (oref comm session)
|
|
:endpoint (plist-get endpoints :hb)))
|
|
(cl-loop
|
|
for channel in '(:stdin :shell :iopub)
|
|
do (setf (slot-value comm (jupyter-comm--channel channel))
|
|
(make-jupyter-proxy-channel
|
|
:endpoint (plist-get endpoints channel)
|
|
:alive-p nil)))))
|
|
|
|
(cl-defmethod jupyter-comm-start ((comm jupyter-channel-ioloop-comm))
|
|
(with-slots (ioloop session) comm
|
|
(unless (jupyter-ioloop-alive-p ioloop)
|
|
(jupyter-ioloop-start ioloop session comm))
|
|
(cl-loop
|
|
for channel in '(:hb :shell :iopub :stdin)
|
|
do (jupyter-start-channel comm channel))))
|
|
|
|
(cl-defmethod jupyter-comm-stop ((comm jupyter-channel-ioloop-comm))
|
|
(cl-loop
|
|
for channel in '(:hb :shell :iopub :stdin)
|
|
do (jupyter-stop-channel comm channel))
|
|
(cl-call-next-method))
|
|
|
|
;;;; `jupyter-channel-ioloop' events
|
|
|
|
(cl-defmethod jupyter-ioloop-handler ((_ioloop jupyter-channel-ioloop)
|
|
(comm jupyter-channel-ioloop-comm)
|
|
(event (head stop-channel)))
|
|
(setf (jupyter-proxy-channel-alive-p
|
|
(slot-value comm (jupyter-comm--channel (cadr event))))
|
|
nil))
|
|
|
|
(cl-defmethod jupyter-ioloop-handler ((_ioloop jupyter-channel-ioloop)
|
|
(comm jupyter-channel-ioloop-comm)
|
|
(event (head start-channel)))
|
|
(setf (jupyter-proxy-channel-alive-p
|
|
(slot-value comm (jupyter-comm--channel (cadr event))))
|
|
t))
|
|
|
|
;;;; Channel querying methods
|
|
|
|
(cl-defmethod jupyter-channel-alive-p ((comm jupyter-channel-ioloop-comm) channel)
|
|
(if (eq channel :hb) (jupyter-channel-alive-p (oref comm hb))
|
|
(with-slots (ioloop) comm
|
|
(and ioloop (jupyter-ioloop-alive-p ioloop)
|
|
(jupyter-proxy-channel-alive-p
|
|
(slot-value comm (jupyter-comm--channel channel)))))))
|
|
|
|
(cl-defmethod jupyter-channels-running-p ((comm jupyter-channel-ioloop-comm))
|
|
"Are any channels of CLIENT running?"
|
|
(cl-loop
|
|
for channel in '(:shell :iopub :stdin :hb)
|
|
thereis (jupyter-channel-alive-p comm channel)))
|
|
|
|
;;;; Channel start/stop methods
|
|
|
|
(cl-defmethod jupyter-stop-channel ((comm jupyter-channel-ioloop-comm) channel)
|
|
(when (jupyter-channel-alive-p comm channel)
|
|
(if (eq channel :hb) (jupyter-stop-channel (oref comm hb))
|
|
(with-slots (ioloop) comm
|
|
(jupyter-send ioloop 'stop-channel channel)
|
|
;; Verify that the channel stops
|
|
(or (jupyter-ioloop-wait-until ioloop 'stop-channel
|
|
(lambda (_) (not (jupyter-channel-alive-p comm channel))))
|
|
(error "Channel not stopped in ioloop subprocess (%s)" channel))))))
|
|
|
|
(cl-defmethod jupyter-start-channel ((comm jupyter-channel-ioloop-comm) channel)
|
|
(unless (jupyter-channel-alive-p comm channel)
|
|
(if (eq channel :hb) (jupyter-start-channel (oref comm hb))
|
|
(let ((endpoint (jupyter-proxy-channel-endpoint
|
|
(slot-value comm (jupyter-comm--channel channel)))))
|
|
(with-slots (ioloop) comm
|
|
(jupyter-send ioloop 'start-channel channel endpoint)
|
|
;; Verify that the channel starts
|
|
(or (jupyter-ioloop-wait-until ioloop 'start-channel
|
|
(lambda (_) (jupyter-channel-alive-p comm channel)))
|
|
(error "Channel not started in ioloop subprocess (%s)" channel)))))))
|
|
|
|
(provide 'jupyter-channel-ioloop-comm)
|
|
|
|
;;; jupyter-channel-ioloop-comm.el ends here
|